home *** CD-ROM | disk | FTP | other *** search
/ Atari Mega Archive 2 / Atari Mega Archive CD - Volume 2.iso / 8bit / cislib_b / qset.asm < prev    next >
Encoding:
Assembly Source File  |  1995-04-22  |  5.9 KB  |  264 lines
  1.          .TITLE "PERCOM QUICK SET      05-27-85" 
  2. ; 
  3. ;SAVE#D:QSET.M65 
  4. ; 
  5. ; This program switches the density for 
  6. ; PERCOM compatible drives. 
  7. ; Drive numbers allowed are 1 through 8. 
  8. ; Allowed settings are: 
  9. ; S  = single 
  10. ; E  = enhanced (1050) 
  11. ; D  = double 
  12. ; DD = double sided, double density 
  13. ; Command format example: 
  14. ; 
  15. ; QSET 1D 7E 3DD 
  16. ; 
  17. ; At least one space after QSET is 
  18. ; required. The rest of the command line 
  19. ; ignores anything other than a number 
  20. ; in the range 1 through 8 followed by 
  21. ; an upper case D, E, or S. Thus, 
  22. ; equivalent examples are: 
  23. ; 
  24. ; QSET 1D7E3DD 
  25. ; QSET 31DXYZ7E          3DD 
  26. ; 
  27. ; When the program terminates, it echoes 
  28. ; to the screen the valid portions of 
  29. ; the command line. The last example 
  30. ; would echo: 
  31. ; 
  32. ;  1D   7E          3DD 
  33. ; 
  34. ; If a drive cannot be configured, the 
  35. ; last letter is replaced with a 
  36. ; question mark. 
  37. ; 
  38. ;    NOTES: 
  39. ;    1. Enhanced (1050) allows 
  40. ;    you to read or write 1050 
  41. ;    density disks, but does 
  42. ;    not allow you to format 
  43. ;    disks in that density. 
  44. ;    2. As with any other SIO 
  45. ;    use, the 28 second timeout 
  46. ;    may occasionally occur. 
  47. ; 
  48. ; I wish to credit DANIEL L. MOORE 
  49. ; for his SET.ASM, from which the 
  50. ; central routine of this program was 
  51. ; adapted. 
  52. ; 
  53. ****************************** 
  54. *                            * 
  55. *  Josef W. Segur  05/27/85  * 
  56. *                            * 
  57. ****************************** 
  58. ; 
  59. DOSVEC   =   $0A 
  60. DOSINIT  =   $07E0   FMS v. 2 
  61. FR0      =   $D4     FP register 0 
  62. DENSITY  =   FR0+2 
  63. ; 
  64. ; OS/A+ equates 
  65. CPBUFP   =   $0A     next char. 
  66. CPCMDB   =   $3F     command buff. 
  67. ; SIO equates 
  68. DDEVIC   =   $0300 
  69. DUNIT    =   $0301 
  70. DCOMND   =   $0302 
  71. DSTATS   =   $0303 
  72. DBUFLO   =   $0304 
  73. DBYTLO   =   $0308 
  74. ; Data direction control 
  75. IN       =   $40 
  76. OUT      =   $80 
  77. ; CIO equates 
  78. ICHID    =   $0340 
  79. ICCOM    =   $0342 
  80. ICBAL    =   $0344 
  81. ICBAH    =   $0345 
  82. ICBLL    =   $0348 
  83. ICBLH    =   $0349 
  84. ; 
  85. PUTBYTS  =   $0B 
  86. ; PERCOM drive table 
  87. READ     =   $4E 
  88. WRITE    =   $4F 
  89. LENGTH   =   12 
  90. FM       =   0       FM recording 
  91. MFM      =   4       MFM recording 
  92. SID1     =   0       One side 
  93. SID2     =   1       Two sides 
  94. ; 
  95. CIO      =   $E456 
  96. SIO      =   $E459 
  97. ; 
  98. EOL      =   $9B     End of line char. 
  99. ; 
  100.          *=  $4000 
  101. ; 
  102. START    CLC  
  103.          LDY #CPBUFP 
  104.          LDA (DOSVEC),Y 
  105.          ADC #CPCMDB+1 ;skip 1st space 
  106.          STA CMDBIX 
  107.          STA FIRSTX 
  108.          SEC  
  109.          LDA # <EBUF 
  110.          SBC FIRSTX 
  111.          STA FR0 
  112.          LDA # >EBUF 
  113.          SBC #0 
  114.          STA FR0+1 
  115.          LDA #EOL 
  116.          STA EBUF 
  117. LOOP     LDY CMDBIX 
  118.          INC CMDBIX 
  119.          BMI DOS     ;out if too long 
  120.          LDA (DOSVEC),Y ;Get char 
  121.          CMP #EOL 
  122.          BEQ DOS     ;out if end 
  123.          STA (FR0),Y ;save for echo? 
  124. ; Test for drive 1 to 8. 
  125.          EOR #'0 
  126.          CMP #$09 
  127.          BCC NUM     ;BR if 1 - 8 
  128. SPLP     LDA #32     ;Else space 
  129.          STA (FR0),Y 
  130.          JMP LOOP    ;and check next 
  131. NUM      STA DUNIT 
  132.          LDA #$31 
  133.          STA DDEVIC 
  134. ; Test for S(0), E(1), D(2), DD(3) 
  135.          LDX #0 
  136.          INY  
  137.          LDA (DOSVEC),Y 
  138.          CMP #EOL 
  139.          BEQ DOS     ;out if end 
  140.          CMP #'S 
  141.          BEQ SETIT 
  142.          INX  
  143.          CMP #'E 
  144.          BEQ SETIT 
  145.          INX  
  146.          CMP #'D 
  147.          BEQ SECD    ;Chk 2nd D 
  148.          DEY         ;letter bad 
  149.          BNE SPLP    ;clr number & next 
  150. SECD     STA (FR0),Y 
  151.          INY  
  152.          LDA (DOSVEC),Y 
  153.          CMP #'D 
  154.          BEQ DDYS 
  155.          DEY         ;whoops 
  156.          LDA #'D 
  157.          BNE SETIT 
  158. DDYS     INX  
  159.          BNE SETIT 
  160. ; 
  161. DOS      LDA #EOL 
  162.          STA (FR0),Y 
  163.          STY CMDBIX 
  164.          JSR DOSINIT ;reinit for all changes 
  165.          LDA ICHID 
  166.          BMI DRTS    ;BR IOCB#0 not open 
  167.          LDA #PUTBYTS 
  168.          STA ICCOM   ;Else echo cmds 
  169.          LDA # <EBUF 
  170.          STA ICBAL   ;from EBUF 
  171.          LDA # >EBUF 
  172.          STA ICBAH 
  173.          LDX #0 
  174.          SEC  
  175.          LDA CMDBIX 
  176.          SBC FIRSTX 
  177.          STA ICBLL   ;len end - start 
  178.          STX ICBLH 
  179.          JSR CIO 
  180. DRTS     RTS  
  181. ; 
  182. SETIT    STX DENSITY 
  183.          STA (FR0),Y ;save letter 
  184.          INY  
  185.          STY CMDBIX  ;& index past it 
  186. ; First read in the current 
  187. ; control table. 
  188.          LDA #IN 
  189.          STA DSTATS 
  190.          LDA #READ 
  191.          STA DCOMND 
  192.          LDA #LENGTH 
  193.          STA DBYTLO 
  194.          LDA #0 
  195.          STA DBYTLO+1 
  196.          LDA # <TABLE 
  197.          STA DBUFLO 
  198.          LDA # >TABLE 
  199.          STA DBUFLO+1 
  200.          JSR SIO 
  201.          BPL DENS    cont if no error 
  202.          LDY CMDBIX 
  203.          DEY  
  204.          LDA #'? 
  205.          STA (FR0),Y else insert ? 
  206.          JMP LOOP    and loop for more 
  207. ; 
  208. ; Modify the control bytes 
  209. ; First recording technique 
  210. DENS     LDA DENSITY 
  211.          BNE SET.MFM 
  212.          LDX #FM 
  213.          BEQ SET 
  214. SET.MFM  LDX #MFM 
  215. SET      STX TABLE+5 
  216. ; Then set the sector length 
  217.          CMP #2 
  218.          BCS S.256 
  219.          LDX #$80    128 bytes 
  220.          LDY #$00 
  221.          BEQ SETLEN 
  222. S.256    LDX #$00    256 bytes 
  223.          LDY #$01 
  224. SETLEN   STY TABLE+6 High byte 
  225.          STX TABLE+7 Low byte 
  226. ; Then set the number of 
  227. ; sectors per track. 
  228.          CMP #1 
  229.          BEQ S.26 
  230.          LDX #18     18 sectors 
  231.          BNE SETSECT 
  232. S.26     LDX #26     26 sectors 
  233. SETSECT  STX TABLE+3 
  234. ; Set the number of sides 
  235.          CMP #3 
  236.          BEQ S.DBL 
  237.          LDX #SID1 
  238.          BEQ SETSID 
  239. S.DBL    LDX #SID2 
  240. SETSID   STX TABLE+4 
  241. ; Then write the table out. 
  242.          LDA #OUT 
  243.          STA DSTATS 
  244.          LDA #WRITE 
  245.          STA DCOMND 
  246.          JSR SIO 
  247. ; Loop for any more requests 
  248.          JMP LOOP 
  249. ; 
  250. CMDBIX   =   *       ;reserve index byte store 
  251.          *=  *+1 
  252. ; 
  253. FIRSTX   =   *       ;reserve start index store 
  254.          *=  *+1 
  255. ; 
  256. ; DRIVE table. 
  257. TABLE    =   * 
  258.          *=  *+LENGTH 
  259. ; 
  260. EBUF     =   * 
  261.          *=  *+128   ;reserve 
  262. ; 
  263. END      .OPT LIST 
  264. ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^